LimitAtInfinity.mws

Limits at Infinity

>    restart;
with( plots ): 

Warning, the name changecoords has been redefined

>   

Lesson Overview

A limit at infinity is a limit in which the independent variable increases without bound. When we write limit(f(x),x = infinity)  it is tempting to say that the limit point is infinity. But, infinity is not a real number and the limit requires special treatment in terms of the precise definition. We will not, however, devote any time to this epsilon-delta definition of limits at infinity. Instead we will concentrate on developing the intuitive understanding of limits at infinity and manipulative skills needed to evaluate these limits.

In this lesson we will learn a few techniques for evaluating limits at infinity without the use of a graph. In spite of the previous comments about the difficulties visualizing a limit at infinity, we will see how graphs can be used to assist with the evaluation of a limit at infinity. The Infinite Limits lesson continues some of the topics introduced here.

>   

Reciprocal Powers and Rational Functions

The fundamental fact used to evaluate all limits at infinity for a rational function is the rather obvious statement

  limit(1/x,x = infinity) = limit(x^(-1),x = infinity)  = 0.

The Product, Power and Root Laws can be used to derive the limit at infinity for any (negative) power

  limit(1/(x^k),x = infinity)  = limit(x^(-k),x = infinity)  = 0  for all k >0

If k = 0 , then 1/(x^0)  = x^0  = 1 for all x <> 0  and so

  limit(x^0,x = infinity)  = limit(1,x = infinity)  = 1

The limits at infinity for positive powers of x will be discussed in the Infinite Limits lesson.

>   

Graphical verification of these results is not really necessary. But, it is important that you thoroughly understand that 1/(x^k)  decreases towards zero more rapidly than 1/(x^m)  when k > m >0. This point is emphasized with the following plot.

>    K := [ 0, 1/2, 1, 2, 3, 4]:
ff := [seq( 1/x^k, k=K )]:
ll := [seq( sprintf("k=%a",k), k=K )]:
plot( ff, x=0..10, y=0..1.2,
      title="Plots of y=1/x^k for large positive values of x",
      legend=ll,
      color=[red,green,pink,cyan,blue,magenta] );

[Maple Plot]

>   

The limit at infinity of a rational function in x  is typically evaluated by identifying the largest power of x  in the denominator and dividing both numerator and denominator by this power of x . The expression obtained from this manipulation will have a denominator whose limit at infinity exists and is not zero. If the numerator contains no positive powers of x , then the Quotient Rule can be used to determine the value of this limit at infinity. The case with positive powers of x  in the numerator will be discussed in the Infinite Limits lesson.

>   

Example 1

For our first example, let's consider the limit at infinity of a rational function in which the numerator and denominator are both quintic polynomials

>    f1 := (63*x^5-39*x^4-48*x^3-94*x^2+10*x-20)/(70*x^5+98*x^4+58*x^3+45*x^2-12*x+28):
n1 := numer( f1 ):
d1 := denom( f1 ):
L1 := Limit( f1, x=infinity ):
L1;

Limit((63*x^5-39*x^4-48*x^3-94*x^2+10*x-20)/(70*x^5+98*x^4+58*x^3+45*x^2-12*x+28),x = infinity)

The leading degree in the denominator is

>    k := degree(d1);

k := 5

Dividing both numerator and denominator by x^k = x^5  produces the equivalent problem

>    n2 := expand( n1/x^k ):
d2 := expand( d1/x^k ):
f2 := n2/d2:
L2 := Limit( f2, x=infinity ):
L1 = L2;

Limit((63*x^5-39*x^4-48*x^3-94*x^2+10*x-20)/(70*x^5+98*x^4+58*x^3+45*x^2-12*x+28),x = infinity) = Limit((63-39/x-48/x^2-94/x^3+10/x^4-20/x^5)/(70+98/x+58/x^2+45/x^3-12/x^4+28/x^5),x = infinity)

Note that the limit of the denominator exists and is non-zero:

>    d3 := Limit( d2, x=infinity ):
d3 = value(d3);

Limit(70+98/x+58/x^2+45/x^3-12/x^4+28/x^5,x = infinity) = 70

The Quotient Rule for limits can be applied to determine the value for this limit

>    L3 := Limit( n2, x=infinity ) / d3:
L2 = L3;
`` = value( L3 );

Limit((63-39/x-48/x^2-94/x^3+10/x^4-20/x^5)/(70+98/x+58/x^2+45/x^3-12/x^4+28/x^5),x = infinity) = Limit(63-39/x-48/x^2-94/x^3+10/x^4-20/x^5,x = infinity)/Limit(70+98/x+58/x^2+45/x^3-12/x^4+28/x^5,x = i...

`` = 9/10

>   

A plot of this function confirms that this result is reasonable.

>    plot( f1, x=1..200, discont=true );

[Maple Plot]

Note, however, that the graph is insufficient without the algebraic manipulation. It is possible that the function appears to settle down on a finite interval but has different behavior for even larger values of x .

>   

Example 2

Consider the limit at infinity of a rational function in which the denominator has a higher degree than the numerator:

>    f1 := (93*x^6+45*x^5+81*x^4+8*x^2-44*x-80)/(63*x^9-24*x^8-63*x^7-36*x^5+85*x^3+35):
n1 := numer( f1 ):
d1 := denom( f1 ):
L1 := Limit( f1, x=infinity ):
L1;

Limit((93*x^6+45*x^5+81*x^4+8*x^2-44*x-80)/(63*x^9-24*x^8-63*x^7-36*x^5+85*x^3+35),x = infinity)

The leading degree in the denominator is

>    k := degree(d1);

k := 9

Dividing both numerator and denominator by x^k = x^9  produces the equivalent problem

>    n2 := expand( n1/x^k ):
d2 := expand( d1/x^k ):
f2 := n2/d2:
L2 := Limit( f2, x=infinity ):
L1 = L2;

Limit((93*x^6+45*x^5+81*x^4+8*x^2-44*x-80)/(63*x^9-24*x^8-63*x^7-36*x^5+85*x^3+35),x = infinity) = Limit((93/x^3+45/x^4+81/x^5+8/x^7-44/x^8-80/x^9)/(63-24/x-63/x^2-36/x^4+85/x^6+35/x^9),x = infinity)

Note that the limit in the denominator exists and is non-zero:

>    d3 := Limit( d2, x=infinity ):
d3 = value(d3);

Limit(63-24/x-63/x^2-36/x^4+85/x^6+35/x^9,x = infinity) = 63

The Quotient Rule for limits can be applied to determine the value for this limit

>    L3 := Limit( n2, x=infinity ) / d3:
L2 = L3;
`` = value( L3 );

Limit((93/x^3+45/x^4+81/x^5+8/x^7-44/x^8-80/x^9)/(63-24/x-63/x^2-36/x^4+85/x^6+35/x^9),x = infinity) = Limit(93/x^3+45/x^4+81/x^5+8/x^7-44/x^8-80/x^9,x = infinity)/Limit(63-24/x-63/x^2-36/x^4+85/x^6+35...

`` = 0

>   

A plot of this function confirms that this result is reasonable.

>    plot( f1, x=1..10, discont=true );

[Maple Plot]

Note, however, that the graph is insufficient without the algebraic manipulation. It is possible that the function appears to settle down on a finite interval but has different behavior for even larger values of x .

>   

Periodic Functions

The functions sin(theta)  and cos(theta)  are periodic with period 2*Pi . This means every value between -1 and 1 (inclusive) is attained for arbitrarily large values of theta . Thus, their limits at infinity do not exist:

  limit(sin(theta),theta = infinity)  = d.n.e.
  limit(cos(theta),theta = infinity)  = d.n.e.

>    plot( [sin(theta),cos(theta)], theta=0..50, color=[red,blue],
      legend=["y=sin(theta)","y=cos(theta)"] );

[Maple Plot]

>   

Example 3

Consider the limit at infinity of a product between a periodic function and a rational function.

>    f1 := sin(x)*(x-1)/(x^2+x+1):
L1 := Limit( f1, x=infinity ):
L1;

Limit(sin(x)*(x-1)/(x^2+x+1),x = infinity)

The function in this example is the product of a periodic function and a rational expression. The rational function in this example is seen to approach zero as x increases without bound. The Product Rule cannot be used to conclude that this limit is zero because limit(sin(x),x = infinity)  does not exist. In situations like this the Squeeze Theorem can be applied. The fact that the periodic function in this problem is bounded ( -1 <= sin(x)  <= 1 ) for all x  and the rational function is positive for all x >1 allows us to conclude that

  -(x-1)/(x^2+x+1)  <= sin(x)*(x-1)/(x^2+x+1)  <= (x-1)/(x^2+x+1)   for all x >1.

Graphical confirmation of this result is obtained with

>    P2 := plot( [sin(theta),cos(theta)], theta=0..50, legend=["y=sin(theta)","y=cos(theta)"], color=[red,blue] ):
g1 := (x-1)/(x^2+x+1):
f1 := sin(x)*g1:
plot( [f1, abs(g1),-abs(g1)], x=10..200,
      legend=["y=sin(x)*(x-1)/(x^2+x+1)", "y=(x-1)/(x^2+x+1)", "y=-(x-1)/(x^2+x+1)"],
      color=[red,blue,cyan] );

[Maple Plot]

Now, because

>    L2 := Limit( g1, x=infinity ):
L2 = value( L2 );

Limit((x-1)/(x^2+x+1),x = infinity) = 0

and

>    L3 := Limit( -g1, x=infinity ):
L3 = value( L3 );

Limit(-(x-1)/(x^2+x+1),x = infinity) = 0

the Squeeze Theorem tells us that

>    L1 = value( L2 );

Limit(sin(x)*(x-1)/(x^2+x+1),x = infinity) = 0

>   

Limits at Negative Infinity

Limits at negative infinity can be converted to limits at infinity by a simple change for variables

  limit(f(x),x = -infinity) = limit(f(-x),x = infinity)  .

The limits limit(1/(x^k),x = -infinity) = limit(1/((-x)^k),x = infinity)  can be evaluated only when (-x)^k  is defined. This means that k  must be either an integer or a rational number with an odd denominator. The graph of 1/(x^k)  for negative values of x  is closely related to the corresponding graph for positive values of x , but the exact relationship depends on whether x^k  is an even or an odd function.

>    plot( ff, x=-10..0, y=-1.2..1.2,
      title="Plots of y=1/x^k for large negative values of x",
      legend=ll, color=[red,green,pink,cyan,blue,magenta] );

[Maple Plot]

>   

Therefore, for k = 0

  limit(1/(x^0),x = -infinity)  = 1  

and for all positive rational values of k = p/q  (in reduced form) with q  odd,

  limit(1/(x^k),x = -infinity)  = 0  .

The fact limits at negative infinity are easily converted to limits at infinity means the techniques developed for limits at infinity can also be applied to limits at negative infinity.

>   

Example 4

Note

Except that infinity  is changed to -infinity , this discussion is exactly the same as the one in Example 1.

For our fourth example, let's consider the limit at negative infinity of a rational function in which the numerator and denominator are both quintic polynomials

>    f1 := (63*x^5-39*x^4-48*x^3-94*x^2+10*x-20)/(70*x^5+98*x^4+58*x^3+45*x^2-12*x+28):
n1 := numer( f1 ):
d1 := denom( f1 ):
L1 := Limit( f1, x=-infinity ):
L1;

Limit((63*x^5-39*x^4-48*x^3-94*x^2+10*x-20)/(70*x^5+98*x^4+58*x^3+45*x^2-12*x+28),x = -infinity)

The leading degree in the denominator is

>    k := degree(d1);

k := 5

Dividing both numerator and denominator by x^k = x^5  produces the equivalent problem

>    n2 := expand( n1/x^k ):
d2 := expand( d1/x^k ):
f2 := n2/d2:
L2 := Limit( f2, x=-infinity ):
L1 = L2;

Limit((63*x^5-39*x^4-48*x^3-94*x^2+10*x-20)/(70*x^5+98*x^4+58*x^3+45*x^2-12*x+28),x = -infinity) = Limit((63-39/x-48/x^2-94/x^3+10/x^4-20/x^5)/(70+98/x+58/x^2+45/x^3-12/x^4+28/x^5),x = -infinity)

Note that the limit of the denominator exists and is non-zero:

>    d3 := Limit( d2, x=-infinity ):
d3 = value(d3);

Limit(70+98/x+58/x^2+45/x^3-12/x^4+28/x^5,x = -infinity) = 70

The Quotient Rule for limits can be applied to determine the value for this limit

>    L3 := Limit( n2, x=-infinity ) / d3:
L2 = L3;
`` = value( L3 );

Limit((63-39/x-48/x^2-94/x^3+10/x^4-20/x^5)/(70+98/x+58/x^2+45/x^3-12/x^4+28/x^5),x = -infinity) = Limit(63-39/x-48/x^2-94/x^3+10/x^4-20/x^5,x = -infinity)/Limit(70+98/x+58/x^2+45/x^3-12/x^4+28/x^5,x =...

`` = 9/10

>   

A plot of this function confirms that this result is reasonable.

>    plot( f1, x=-1000..-10, discont=true );

[Maple Plot]

Note, however, that the graph is insufficient without the algebraic manipulation. It is possible that the function appears to settle down on a finite interval but has different behavior for even larger values of x .

>   

>   

Horizontal Asymptote

Definition - Horizontal Asymptote

A horizontal asymptote  to the graph of y = f(x)  is a (horizontal) line y = y[h]  where limit(f(x),x = infinity) = y[h]  or limit(f(x),x = -infinity) = y[h] .

>   

Example 5

Find the horizontal asymptote(s) for f(x) = (3*x^5+1)/(abs(x)^5+5*x^2+1)+10*sin(x)/(x^2+1) .

While the first term in this function is not a rational function, it can be handled exactly the same manner. Limits for the second term can be evaluated with the assistance of the Squeeze Theorem (as in Example 3).

>    f := (3*x^5+1)/(abs(x)^5+5*x^2+1) + 10*sin(x)/(x^2+1);

f := (3*x^5+1)/(abs(x)^5+5*x^2+1)+10*sin(x)/(x^2+1)

Observe that for x  > 0, abs(x) = x  and so f(x) = (3*x^5+1)/(x^5+5*x^2+1)+10*sin(x)/(x^2+1) . The limit at infinity of this function is easily seen to be 3 :

>    y_h1 := limit( f, x=infinity );

y_h1 := 3

Similarly, for x  < 0, abs(x) = -x  and so f(x) = (3*x^5+1)/(-x^5+5*x^2+1)+10*sin(x)/(x^2+1) . The limit at negative infinity of this function is easily seen to be -3 :

>    y_h2 := limit( f, x=-infinity );

y_h2 := -3

>   

Graphical verification of these results can be seen in the following plot.

>    plot( [ f, y_h1, y_h2 ], x=-20..20, y=-5..5, discont=true,
       color=[red,blue,green], legend=["y=f(x)", "y=3", "y=-3"] );

[Maple Plot]

Notice how the function oscillates but settles down to y = 3  for large positive values of x  and to y = -3  for large negative values of x .

>   

Lesson Summary

One of the main tools in the evaluation of limits at infinity (or negative infinity) is the fact

  limit(1/(x^k),x = infinity) = PIECEWISE([0, `k > 0`],[1, k = 0])   

This fact is utilized to evaluate limits at infinity of rational functions. One of the fundamental applications of limits at infinity is to find the horizontal asymptote(s) for a function.

>   

What's Next?

A collection of online practice problems are provided to help you develop your skills working with limits at infinity. Once you are proficient with these problems, complete both the online homework assignment and the textbook homework assignment.

The Infinite Limits lesson continues the discussion of limits and infinity. Two of the topics of discussion in this lesson will be limits at infinity of rational polynomials where the degree of the numerator is larger than the degree of the denominator and vertical and oblique asymptotes.

>   

>   

>