LimitPrecise.mws

The Precise Definition of a Limit

>    restart;
with( plots ): 

Warning, the name changecoords has been redefined

>   

Lesson Overview

The processes for evaluating limits described in the Conceptual Understanding of the Limit lesson can be summarized in the following informal definition:

Definition: Informal Definition of Limit

The statement Limit(f(x),x = a) = L   means the difference between f(x)  and L  can be made as small as desired for all values of x  sufficiently close to -- but different from --   a .

>   

The development of general tools for working with and applying limits requires a more precise definition of limit. The following definition provides a framework upon which we will be able to develop a wide range of useful techniques.

Definition: Precise, or epsilon-delta , Definition of Limit

  Limit(f(x),x = a) = L  if and only if for every   epsilon  > 0 there exists a number   delta  > 0 with the property that

 if 0 < abs(x-a)  < delta   (and x  is in the domain of f), then   abs(f(x)-L)  < epsilon  .

>   

This definition can be difficult to understand. Do not be concerned if it does not make sense to you right now. The structure of this lesson has designed to help you understand the definition and be able to apply it in some cases.

The first step is to develop a graphical interpretation of the precise definition. Next, the algebraic manipulations involved in applying the precise definition will be explored for four examples. The lesson concludes with a brief discussion of one-sided limits.

>   

Graphical Interpretation of the Limit

The precise definition of a limit looks pretty imposing. The definition becomes much more understandable when it can be expressed graphically. The EpsilonDelta  maplet [ Maplet Viewer] [ MapleNet] provides an excellent interface for visualizing the roles of epsilon  and delta  and for obtaining, as a result, a theoretical understanding of limits.

Example 1: Limit(3*x-4,x = 3) = 5  

1. Follow these steps:

Note that the blue horizontal strip is not contained within the red lines. This means this value of  is too large to satisfy the conditions in the definition of the limit.

>   

2. Change the value of delta  to 0.05 .

Now the blue horizontal strip falls entirely within the red lines. This value of  does satisfy the conditions in the definition of the limit.

But, this is not enough! The definition states that it must be possible to find such a  for every epsilon  > 0. At present we have shown this property is true only for epsilon  = 0.5.

>   

3. Find (exactly or approximately) the largest value of delta  for which the conditions of the definition of the limit are satisfied for epsilon  = 0.50.

>   

4. Repeat 3. for epsilon  = 0.25. (You might to try delta  = 0.1 and delta =0.05 to get started.)

>   

5. Can you make any conjectures about a general rule for selecting delta  for any given epsilon ?

>   

Example 2: Limit(3*x-4,x = 3) <> 2

1. Consider the same limit, but with an incorrect value for the limit (say, L  = 2 ).

2. Choose a (positive) value for epsilon .

3. Can you find a value of delta  that satisfies the conditions of the definition of a limit?

If you can find one value of epsilon  > 0 for which the conditions are not satisfied, this proves that this value of  is incorrect. The limit either has a different value or does not exist.

>   

Example 3: Limit(x^2-3*x+3,x = 3)  

1. Find the value of this limit.

2. Find values of delta  that satisfy the conditions of the definition for epsilon  = 0.50, epsilon  = 0.25, and epsilon  = 0.10.

3. Attempt to find a general formula for delta  in terms of epsilon  that satisfies the conditions of the definition.

>   

Example 4: Limit(sin(Pi*theta) = 0,theta = 0)  

1. Choose a value for epsilon  with epsilon  > 1. Explain why all delta  > 0 satisfy the conditions in the definition.

2. Set epsilon  = 0.50. How small must delta  be to satisfy the conditions in the definition?

3. Repeat 2. with epsilon  = 0.25 and epsilon  = 0.10.

4. Can you find a general formula for delta  that works for all epsilon  > 0?

>   

Example 5: Limit(sin(Pi*theta)/theta,theta = 0) = 1  

1. Find the value of this limit (if it exists).

2. Find values of delta  that satisfy the conditions of the definition for epsilon  = 0.50, epsilon  = 0.25, and epsilon  = 0.10.

>   

Having completed these five examples, you are now ready to learn how to use the definition of limits to prove that a limit has a given value.

>   

Writing epsilon-delta  Proofs for Limits

The graphical interpretation of the definition should have provided a better understanding of the roles of epsilon  and delta  in the precise definition of a limit.

Equipped with this understanding it is now appropriate to look at a few `` epsilon-delta  proofs'' of limits. Examples 6-9 present epsilon-delta  proofs for increasingly complicated functions. As you work through these examples, be sure to test your formulae for delta  in the EpsilonDelta  maplet [ Maplet Viewer] [ MapleNet].

Example 6: Linear Function

>    restart;

Consider the statement that limit(3*x-4,x = 3) = 5 . (This limit has been seen previously in Example 1 of this lesson.) To prove that this statement is correct introduce

>    f := 3*x-4;

f := 3*x-4

>    a := 3;

a := 3

>    L := 5;

L := 5

>   

Our goal is to show that, for any epsilon  > 0, is it possible to find a positive value of delta that assures that if it is given that

>    given := abs( x-a ) < delta:
given;

abs(x-3) < delta

then

>    goal := abs( f-L ) < epsilon:
goal;

abs(3*x-9) < epsilon

>   

The typical proof begins by looking at the left-hand side of the goal:

>    start := lhs( goal ):
start;

abs(3*x-9)

and attempting to identify ways in which this can be bounded by a constant times a power of delta . The most common way of introducing delta  into this expression is to locate factors of . abs(x-a) = abs(x-3) . In this example, it is easy to see that:

>    q1 := start = 3*abs(x-3):
q1;

abs(3*x-9) = 3*abs(x-3)

and so

>    q2 := rhs(q1) < 3*delta:
q2;

3*abs(x-3) < 3*delta

At this point we have shown that

>    q3 := start < rhs(q2):
q3;

abs(3*x-9) < 3*delta

If it is possible to choose delta  so that

>    constraint := rhs(q3) < epsilon:
constraint;

3*delta < epsilon

then the proof will be complete. In this case, the above constraint is satisfied whenever

>    isolate( constraint, delta );

delta < 1/3*epsilon

>   

This process shows that, given any epsilon >0:

if 0 < abs(x-3)  < delta = epsilon/3  then abs(3*x-4-5) = abs(3*x-9)  < 3*delta  < 3 ( epsilon/3 ) = epsilon .

This concludes the proof of this limit.

>   

Example 7: Rational Function at a Removable Singularity

Consider the statement that limit((x^2-9)/(x-3),x = 3) = 6 . To prove that this statement is correct introduce

>    f := (x^2-9)/(x-3);

f := (x^2-9)/(x-3)

>    a := 3;

a := 3

>    L := 6;

L := 6

>   

Our goal is to show that, for any epsilon  > 0, is it possible to find a positive value of delta that assures that if it is given that

>    given := abs( x-a ) < delta:
given;

abs(x-3) < delta

then

>    goal := abs( f-L ) < epsilon:
goal;

abs((x^2-9)/(x-3)-6) < epsilon

>   

The proof begins as in Example 1 by looking at the left-hand side of the goal:

>    start := lhs( goal ):
start;

abs((x^2-9)/(x-3)-6)

and attempting to identify ways in which this can be bounded as in Example 1. The most common way of introducing epsilon  into this expression is to locate factors of abs(x-a) = abs(x-3) . This takes a little more effort than in the previous example. First, note that the condition 0 < abs(x-3)  < delta  implies that x <> 3  and so there is no problem with division by zero. With this potential problem alleviated, find a common denominator and simplify:

>    q1 := start = simplify( start ) assuming x<>3:
q1;

abs((x^2-9)/(x-3)-6) = abs(x-3)

and so

>    q2 := rhs(q1) < delta:
q2;

abs(x-3) < delta

At this point we have shown that

>    q3 := start < rhs(q2):
q3;

abs((x^2-9)/(x-3)-6) < delta

If it is possible to choose epsilon  so that

>    constraint := rhs(q3) < epsilon:
constraint;

delta < epsilon

then the proof will be complete. In this case, the above constraint is satisfied whenever

>    isolate( constraint, delta );

delta < epsilon

>   

This process shows that, given any epsilon >0:

if 0 < abs(x-3)  < delta = epsilon  then abs((x^2-9)/(x-3)-6) = abs(x-3)  < delta  < epsilon .

This concludes the proof of this limit.

>   

Example 8: Power Function

Consider the statement that limit(sqrt(x),x = 3) = sqrt(3) . To prove that this statement is correct introduce

>    f := sqrt(x);

f := x^(1/2)

>    a := 3;

a := 3

>    L := sqrt(3);

L := 3^(1/2)

>   

Our goal is to show that, for any epsilon  > 0, is it possible to find a positive value of delta that assures that if it is given that

>    given := abs( x-a ) < delta:
given;

abs(x-3) < delta

then

>    goal := abs( f-L ) < epsilon:
goal;

abs(x^(1/2)-3^(1/2)) < epsilon

>   

The proof begins as in Examples 1 and 2 by looking at the left-hand side of the goal:

>    start := lhs( goal ):
start;

abs(x^(1/2)-3^(1/2))

and attempting to identify ways in which this can be bounded as in the previous examples. The most common way of introducing delta  into this expression is to locate factors of abs(x-a) = abs(x-3) . This takes a little more effort than in the previous examples. But first, one technicality needs to be addressed. The quantity f(x) = sqrt(x)  is defined (as a real number) only when x  >= 0. This is where the parenthetic remark about x  being in the domain of the function is needed. In this case the condition 0 < abs(x-3)  < delta  must be amended with x  >= 0 to ensure that the expression abs(f(x)-L) = abs(sqrt(x)-sqrt(3))  makes sense.

 Observe that x-3  = sqrt(x)^2-sqrt(3)^2  = (sqrt(x)-sqrt(3))*(sqrt(x)+sqrt(3))  and so sqrt(x)-sqrt(3) = (x-3)/(sqrt(x)+sqrt(3)) . When absolute values are applied:

>    q1 := start = abs((x-3))/abs(sqrt(x)+sqrt(3)):
q1;

abs(x^(1/2)-3^(1/2)) = abs(x-3)/abs(x^(1/2)+3^(1/2))

Our focus is now directed towards the denominator on the right-hand side of the previous expression.

>    d1 := denom( rhs(q1) ):
d1;

abs(x^(1/2)+3^(1/2))

 First, sqrt(x)+sqrt(3)  is always positive so the absolute values are not needed:

>    d2 := d1 = op(d1);

d2 := abs(x^(1/2)+3^(1/2)) = x^(1/2)+3^(1/2)

Moreover, because sqrt(x)  > 0, we see that

>    d3 := rhs(d2) > sqrt(3):
d3;

3^(1/2) < x^(1/2)+3^(1/2)

Taking reciprocals (and noting that Maple has converted the inequality to a <):

>    bound := 1/lhs(d3) > 1/rhs(d3):
bound;

1/(x^(1/2)+3^(1/2)) < 1/3*3^(1/2)

We are now ready to return the full quotient. Recall that

>    q1;

abs(x^(1/2)-3^(1/2)) = abs(x-3)/abs(x^(1/2)+3^(1/2))

The numerator on the right-hand side can be bounded above by epsilon, the remaining term is bounded by the previous argument. The result is

>    q2 := rhs(q1) < delta*rhs(bound):
q2;

abs(x-3)/abs(x^(1/2)+3^(1/2)) < 1/3*delta*3^(1/2)

At this point we have shown that

>    q3 := start < rhs(q2):
q3;

abs(x^(1/2)-3^(1/2)) < 1/3*delta*3^(1/2)

If it is possible to choose delta  so that

>    constraint := rhs(q3) < epsilon:
constraint;

1/3*delta*3^(1/2) < epsilon

then the proof will be complete. In this case, the above constraint is satisfied whenever

>    isolate( constraint, delta );

delta < epsilon*3^(1/2)

>   

This process shows that, given any epsilon >0:

if 0 < abs(x-3)  < delta = sqrt(3)*epsilon  (and x  >= 0) then abs(sqrt(x)-sqrt(3)) = abs(x-3)/(sqrt(x)+sqrt(3))  < delta/sqrt(3)  < epsilon .

This concludes the proof of this limit.

>   

Example 9: Quadratic Function

Consider the statement that limit(x^2-3*x+3,x = 3) = 3 . (This limit has been seen previously in Example 3 of this lesson.) To prove that this statement is correct introduce

>    f := x^2-3*x+3;

f := x^2-3*x+3

>    a := 3;

a := 3

>    L := 3;

L := 3

>   

Our goal is to show that, for any epsilon  > 0, is it possible to find a positive value of delta that assures that if it is given that

>    given := abs( x-a ) < delta:
given;

abs(x-3) < delta

then

>    goal := abs( f-L ) < epsilon:
goal;

abs(x^2-3*x) < epsilon

>   

The proof begins as in all previous examples by looking at the left-hand side of the goal:

>    start := lhs( goal ):
start;

abs(x^2-3*x)

The appearance of abs(x-3)  in this expression is fairly obvious:

>    q1 := start = abs(x)*abs(x-3):
q1;

abs(x^2-3*x) = abs(x)*abs(x-3)

Applying the assumption that abs(x-3)  < delta  leads to:

>    q2 := rhs(q1) < abs(x)*delta:
q2;

abs(x)*abs(x-3) < abs(x)*delta

It now remains to deal with the term abs(x)  on the right-hand side of this equation. The general approach is similar to that takin in Example 3 but the details are a little more involved. The key is to observe that the condition 0 < abs(x-3)  < delta  can be written equivalently as -delta  < x-3  < delta  (and x <> 3 ) or 3-delta  < x  < delta+3 . Now, because 0 < delta , 3+delta  > abs(3-delta)  and so abs(x)  < 3+delta .

>    q3 := rhs(q2) < (3+delta)*delta:
q3;

abs(x)*delta < (3+delta)*delta

>   

If it is possible to choose delta  so that

>    constraint := rhs(q3) < epsilon:
constraint;

(3+delta)*delta < epsilon

then the proof will be complete. In this case, the above constraint is satisfied whenever

>    solve( constraint, delta );

>   

Well, the fact that Maple's response is empty means that Maple was unable to solve this inequality. If the inequality is converted to an equality

>    c2 := convert( constraint, equality ):
c2;

(3+delta)*delta = epsilon

it becomes apparent that this is a quadratic in delta  (with epsilon  as a parameter). The two roots are

>    r := solve( c2, delta );

r := -3/2+1/2*(9+4*epsilon)^(1/2), -3/2-1/2*(9+4*epsilon)^(1/2)

These roots are real because epsilon >0. Moreover, one is positive and one is negative. It is not too difficult to now determine that the constraint is satisfied for all delta  with 0 < delta  < -3/2+1/2*(9+4*epsilon)^(1/2)  .

>   

This process shows that, given any epsilon >0:

if 0 < abs(x-3)  < delta = -3/2+sqrt(9+4*epsilon)/2  then abs(x^2-3*x+3-3) = abs(x)*abs(x-3)  < (3+delta)*delta  < epsilon .

This concludes the proof of this limit.

>   

One-Sided Limits

For two-sided limits, values of the independent variable on both sides of the limit point must be considered (assuming they are in the domain of the function). One-sided limits only consider values of the independent variable on one side of the limit point. These differences are summarized in the following table.

  MATRIX([[`Type of Limit`, `Values of Independent Variable (Compact Form)`, `Values of Independent Variable (Long Form)`], [_____________, _________________________________________, ____________________...  

Proofs involving one-sided limits follow the same general pattern as a two-sided limit. The primary difference is that it is possible to use the additional property that x  > a  (right-hand limit) or x  < a  (left-hand limit).

>   

Lesson Summary

The picture that should be associated when using the definition of the limit to show limit(f(x),x = a) = L  should contain the following features:

  [Maple Plot]  

If the value of delta  is consistent with the definition of the limit then each value of x  in the vertical band (except, possibly, x = a ) will produce a function value that is within the horizontal band. If there is even one function value outside this horizontal band then either the value of delta  is too large for this epsilon  or the limit value ( L ) is incorrect.

Limit proofs are easiest to complete when it is possible to write abs(f(x)-L)  as the product of a power of abs(x-a)  and an expression that is bounded.

>   

What's Next?

You are now ready to work some problems on your own. To test your mastery of these concepts, complete the textbook assignment and the online homework assignment. If you need additional practice on a particular type of problem, please spend some time working on the related Practice Problems.

The next lesson develops a collection of Limit Laws that can be used instead of an epsilon-delta  proof..

>   

>   

>