Lab Overview

This lab introduces and explores a pharmaceutical problem that is best addressed with mathematics.  When we take (or are given) medication, the concentration of the drug in the bloodstream is not constant. The drug is effective when the concentration is above a certain threshold.  Oftentimes there is also an upper limit on the concentration above which the drug becomes toxic.  Two different models will be formulated.  You know all the mathematics needed to model the drug concentration.  For the Lab Questions, you will be asked to use these models to design a drug treatment regimin meeting specified constraints.

Problem Description

The concentration in the blood resulting from a single dose of a drug normally decreases with time as the drug is eliminated from the body.  In order to determine the exact pattern the decrease follows, experiments are performed in which drug concentrations in the blood are measured at various times after the drug is administered. The data are then checked against a hypothesized function relating drug concentration to time.

We make a simplifying assumption: when the drug is administered, it is diffused so rapidly throughout the bloodstream that, for all practical purposes it reaches its fullest concentration instantaneously.  This assumption is justified for drugs that are administered intravenously, for example, but certainly not for drugs that are taken orally.

Model 1: Constant Rate of Consumption

The rate at which the drug is removed from the blood is the derivative of the concentration: .  If this rate is constant, then the concentration has a constant slope.  Hence, the concentration must be a linear function of time.

>	model1 := C = m*t + b: model1;

The two pieces of information for Drug A can be used to obtain 2 equations for the 2 unknown parameters in the model: the slope  and the "intercept" :

>	dataA1; dataA2;

>	eqnA1 := eval( model1, dataA1 ); eqnA2 := eval( model1, dataA2 );

The solution to these two equations is

>	q1 := solve( { eqnA1, eqnA2 }, { m, b } );

Notice that the "intercept" is better described as the dosage amount.  This is the amount of increase in the concentration when a dose of Drug A is given.

>	if not assigned(m) then assign( q1 ) end if; dosage_amt := b; dose_beg[1] := dosage_amt; dose[1] := rhs(model1): C = dose[1];

The graph of this concentration as a function of time is the straight line in the following plot.

>	plot( dose[1], t=0..10, title="One Dose of Drug A: Concentration vs. Time" );

When is the drug completely removed from the blood?

>

Now, if the medication is readministered at the end of 6 hours, then the concentration at  will be increased by the dosage amount (  mg/ml) from its measured level at the end of the first treatment period ( ).

>	t2 := 6; dose_end[1] := eval( dose[1], t=6 ); dose_beg[2] := dose_end[1] + dosage_amt;

>

Then, over the next 6 hours, the concentration of the drug is a linear function with the same slope as during the first 6 hours. That is, after dose 2 is administered, the concentration is the linear function:

>	dose[2] := dose_beg[2] + m*(t-t2): C = dose[2];

Verify that this linear function has the proper slope and satisfies the condition that the concentration at  is  mg/ml. Thus, the plot of the concentration over the first two treatment periods is

>	P1 := plot( dose[1], t=0..6 ): P2 := plot( dose[2], t=6..12 ): display( [P1,P2], view=[DEFAULT,0..2],          title="Model 1: Two Doses of Drug A\nConcentration vs. Time" );

>

A third dose after 12 hours would be handled in the same way:

>	t3 := 12; dose_end[2] := eval( dose[2], t=t3 ); dose_beg[3] := dose_end[2] + 1; dose[3] := dose_beg[3] + m*(t-t3): C = dose[3];

>	P3 := plot( dose[3], t=12..18 ): display( [P1,P2,P3], view=[DEFAULT,0..2],          title="Model 1: Three Doses of Drug A\nConcentration vs. Time" );

>	dose_end[3] := eval( dose[3], t=18 );

>

Do you see the patterns in the concentration as additional doses of Drug A are administered?

>

HEADER := < `Dose #` | `Conc (beg)` | `Conc (end)` | `Difference` >: R1 := < 1 | dose_beg[1] | dose_end[1] | dose_beg[1]-dose_end[1] >: R2 := < 2 | dose_beg[2] | dose_end[2] | dose_beg[2]-dose_end[2] >: R3 := < 3 | dose_beg[3] | dose_end[3] | dose_beg[3]-dose_end[3] >: R4 := < 4 | `` | `` | `` >: R5 := < 5 | `` | `` | `` >: R6 := < 6 | `` | `` | `` >: R7 := < 7 | `` | `` | `` >: R8 := < 8 | `` | `` | `` >: Model1_Table := < HEADER, R1, R2, R3, R4, R5, R6, R7, R8 >;

>

• What is the drug concentration immediately before doses 4 and 8 of Drug A are administered?
• What is the drug concentration of Drug A after 24 and 48 hours?
• How long does a trace of the drug stay in the blood?
• What would happen if the drug were administered for a full week?

>

Model 2: Proportional Rate of Consumption

As above, let  denote the concentration of the drug in the blood at time . Then the rate of change of the concentration, , is proportional to the concentration if

>	unassign( 'c','k' ); ode2 := diff( C(t), t ) = k*C(t): ode2;

This differential equation is separable and can be solved by the methods discussed in Math 141 (see Section 5.2 of Varberg, Purcell, and Rigdon). The solution to this differential equation with initial condition

>	ic2 := C(0) = c: ic2;

is

>	q2 := dsolve( {ode2,ic2}, C(t) ): model2 := C = rhs(q2): model2;

As for Model 1, the experimental data for Drug A can be used to find two equations from which the parameters  and  can be determined.  Recall that the data points are

>	dataA1; dataA2;

The corresponding two equations for  and  are

>	eqnA3 := eval( model2, dataA1 ); eqnA4 := eval( model2, dataA2 );

The solution to these equations is

>	q3 := solve( {eqnA3,eqnA4}, {c,k} ): q3;

Observe that coefficient of the exponential function is the concentration of the drug immediately after the drug enters the bloodstream.  The dosage amount is the coefficient of the exponential function for the initial treatment period .  Thus, after one dose of Drug A, the concentration in the blood is

>	if not assigned(`k`) then assign( q3 ) end if; t1 := 0; dosage_amt := c; dose_beg[1] := dosage_amt; dose[1] := dose_beg[1] * exp( k*(t-t1) ): C = dose[1];

>	plot( dose[1], t=0..24, title="Model 2: One Dose of Drug A\nConcentration vs. Time" );

Notice that because the concentration follows an exponential curve, the drug is never completely removed from the blood.

>

If the medication is readministered at the end of 6 hours, then the concentration at  will be increased by the dosage amount (  mg/ml) from its measured level at the end of the first treatment period.

>	t2 := 6; dose_end[1] := eval( dose[1], t=6 ); dose_beg[2] := dose_end[1] + dosage_amt;

This is unchanged from Model 1. The difference for Model 2 is seen after dose 2 is administered.  Now, the concentration follows an exponential curve with the same decay rate ( ) but the coefficient is the concentration immediately after dose 2 enters the bloodstream.

>	dose[2] := dose_beg[2] * exp( k*(t-t2) );

The graph of the concentration of Drug A in the blood for 2 full treatment periods (12 hours) is shown below.

>	P1 := plot( dose[1], t=0..6 ): P2 := plot( dose[2], t=6..12 ): display( [P1,P2], view=[DEFAULT,0..2],          title="Model 2: Two Doses of Drug A\nConcentration vs. Time" );

>

A third dose after 12 hours would be handled in the same way:

>	t3 := 12; dose_end[2] := eval( dose[2], t=t3 ); dose_beg[3] := dose_end[2] + dosage_amt; dose[3] := dose_beg[3] * exp( k*(t-t3) ): C = dose[3];

>	P3 := plot( dose[3],t=12..18 ): display( [P1,P2,P3], view=[DEFAULT,0..1.5],          title="Model 2: Three Doses of Drug A\nConcentration vs. Time" );

>

>	t4 := 18; dose_end[3] := eval( dose[3], t=t4 );

Continuing this pattern for 8 doses of Drug A will give the concentration of Drug A for a full 2 days (48 hours).  To see the patterns for this model, consider the following table

>

HEAD := < `Dose #` | `Time` | `Conc (beg)` | `Conc (end)` | `Ratio (end/beg)` >: R1 := < 1 | t1 | dose_beg[1] | dose_end[1] | dose_end[1]/dose_beg[1] >: R2 := < 2 | t2 | dose_beg[2] | dose_end[2] | dose_end[2]/dose_beg[2] >: R3 := < 3 | t3 | dose_beg[3] | dose_end[3] | dose_end[3]/dose_beg[3] >: R4 := < 4 | 18 | `` | `` | `` >: R5 := < 5 | 24 | `` | `` | `` >: R6 := < 6 | 30 | `` | `` | `` >: R7 := < 7 | 36 | `` | `` | `` >: R8 := < 8 | 42 | `` | `` | `` >: Model2_Table := < HEAD, R1, R2, R3, R4, R5, R6, R7, R8 >;

Notice the patterns in the the above table.  Use these patterns to complete the remaining five rows of the table.

>

• What is the drug concentration immediately before doses 4 and 8 of Drug A are administered?
• What is the drug concentration of Drug A after 24 and 48 hours?
• How long does a trace of the drug stay in the blood?
• What would happen if the drug were administered for a full week?

>

General Analysis of Model 2

To understand exactly what is happening in Model 2, it is easier to work with the general model.  Let  denote the dosage amount (in mg/ml) for a single dose of the drug,  be the decay rate for the concentration after it enters the bloodstream, and  represents the time between treatments (the treatment period).

>	unassign( 'c', 'k', 'T' );

>

dosage_amt := c: dose_beg[1] := dosage_amt: dose[1] := dose_beg[1] * exp( k*t ): for i from 2 to 8 do   t||i := (i-1)*T;   dose_end[i-1] := eval( dose[i-1], t=(i-1)*T);   dose_beg[i] := simplify( dose_end[i-1] + c );   dose[i] := simplify( dose_beg[i] * exp( k*(t-t||i) ) ); end do: dose_end[i-1] := eval( dose[i-1], t=(i-1)*T ):

Extreme Values of Concentration

Lab Questions