//  Discussion:
//
//    -uxx - uyy = f on the unit square.
//    u  = g on the boundary.
//
//    f = - alpha * ( alpha - 1 ) * x^(alpha-2)
//    g = x^alpha
//
//    The parameter alpha should be 0.5 or greater.  It determines the
//    strength of the singularity.  The suggested value is alpha = 0.6
//
//  Location:
//
//    http://people.sc.fsu.edu/~jburkardt/examples/mitchell_freefem++/test07.edp
//
//  Licensing:
//
//    This code is distributed under the GNU LGPL license.
//
//  Modified:
//
//    19 December 2014
//
//  Author:
//
//    John Burkardt
//
//  Reference:
//
//    Frederic Hecht,
//    Freefem++,
//    Third Edition, version 3.22
//
//    William Mitchell,
//    A collection of 2D elliptic problems for testing adaptive
//    grid refinement algorithms,
//    Applied Mathematics and Computation,
//    Volume 220, 1 September 2013, pages 350-364.
//
border bottom ( t = 0.0, 1.0 )   { x = t;    y = 0.0; label = 1; }
border right  ( t = 0.0, 1.0 )   { x = 1.0;  y = t;   label = 1; }
border top    ( t = 1.0, 0.0 )   { x = t;    y = 1.0; label = 1; }
border left   ( t = 1.0, 0.0 )   { x = 0.0;  y = t;   label = 1; }
//
//  Define Th, the triangulation of the "left" side of the boundaries.
//
int n = 10;
mesh Th = buildmesh ( bottom ( n ) + right ( n ) + top ( n ) + left ( n ) );
//
//  Define Vh, the finite element space defined over Th, using P1 basis functions.
//
fespace Vh ( Th, P1 );
//
//  Define U, V, and F, piecewise continuous functions over Th.
//
Vh u;
Vh v;
//
//  Define parameter.
//
real alpha = 0.6;
//
//  Define function F.
//
func f = - alpha * ( alpha - 1.0 ) * pow ( x, alpha - 2 );
//
//  Define function G.
//
func g = pow ( x, alpha );
//
//  Solve the variational problem.
//
solve Laplace ( u, v ) 
  = int2d ( Th ) ( dx(u)*dx(v) + dy(u)*dy(v) )
  - int2d ( Th ) ( f * v ) 
  + on ( 1, u = g );
//
//  Plot the solution.
//
plot ( u, wait = 1, fill = true, ps = "test07_u.eps" );
//
//  Plot the mesh.
//
plot ( Th, wait = 1, ps = "test07_mesh.eps" );
//
//  Save the mesh file.
//
savemesh ( Th, "test07.msh" );